Fonction RANG Excel (Facile pour débutant)

4.4/5 - (12 votes)

Ce tutoriel explique les spécificités de la fonction RANG Excel. Nous vous montrons comment effectuer un classement dans Excel en fonction de plusieurs critères. Nous vous expliquons aussi comment classer les données par groupe, calculer le rang centile, etc.

Lorsque vous devez déterminer la position relative d’un nombre dans une liste de nombres, le moyen le plus simple consiste à faire un tri croissant ou décroissant. Cependant, le tri Excel change l’ordre de vos lignes de données même si vous ne le souhaitez pas. Heureusement, la formule RANG dans Excel vous permet de voir le classement de vos données tout en les gardant intactes.

Table des matières

Qu’est-ce que la fonction RANG ?

La fonction Excel RANG renvoie la position relative d’une valeur numérique par rapport à une liste d’autres valeurs numériques. RANG Excel peut classer les valeurs de la plus grande à la plus petite, par exemple, les meilleures ventes; ainsi que de la plus petite à la plus grande, par exemple le temps le plus rapide.

La position d’un nombre dans une liste triée serait déterminée par son rang. Dans Excel, la fonction RANG peut déterminer le classement en commençant par la plus grande valeur (comme si vous l’avez trié par ordre décroissant) ou la plus petite valeur (comme si vous l’avez trié par ordre croissant).

RANG Excel -Syntaxe de formule

La syntaxe de la fonction Excel RANG est comme suivant :

=RANG(nombre,référence;[ordre])

La fonction RANG utilise les arguments suivants :

Nombre (argument obligatoire): il s’agit de la valeur pour laquelle vous devez trouver le rang.
Référence (argument obligatoire): il peut être une liste, un tableau ou une référence à des nombres. Il s’agit des valeurs avec lesquelles vous voulez comparer le premier argument.
Ordre (argument facultatif): il s’agit d’un nombre qui spécifie le type de classement à faire (ordre croissant ou décroissant). Vous pouvez utiliser l’une des valeurs suivantes :
- 0 pour l’ordre décroissant;
- 1 pour l’ordre croissant;
- Si vous omettez l’argument, la fonction prendra la valeur par défaut de 0. Elle va donc effectuer un ordre décroissant. En revanche, elle prendra toute valeur non nulle comme valeur 1 (ordre croissant).

Remarques sur l’utilisation de la fonction RANG

La fonction Excel RANG attribue un rang à une valeur numérique par rapport à une liste d’autres valeurs numériques. Utilisez RANG lorsque vous souhaitez afficher un classement pour les valeurs numériques dans une liste. Il n’est pas nécessaire de trier les valeurs dans la liste avant d’utiliser RANG.
La formule RANG Excel renvoie l’erreur #N/A lorsque le nombre donné n’est pas présent dans la référence fournie.
La fonction RANG ne reconnaît pas les représentations textuelles des nombres en tant que valeurs numériques. Ainsi, nous obtiendrons également l’erreur #N/A si les valeurs du tableau « Référence » sont des valeurs textuelles.
Si nous fournissons des valeurs logiques, nous obtiendrons l’erreur « #VALEUR!« .

Contrôle de l’ordre de classement

La fonction RANG a deux modes de fonctionnement, contrôlés par l’argument « ordre« . Pour classer les valeurs dont la valeur la plus élevée est classée #1, définissez l’ordre sur zéro (0). Par exemple, avec les valeurs 1-5 dans la plage A2:A6 :

=RANG(A2;A2:A6;0) // décroissant, renvoie 5

=RANG(A2;A2:A6;1) // croissant, renvoie 1

Définissez l’ordre sur zéro (0) lorsque vous souhaitez classer quelque chose comme les meilleures ventes, où le plus grand nombre de ventes doit se classer au premier rang. En revanche, définissez l’ordre sur un (1) lorsque vous souhaitez classer quelque chose comme les résultats de la course, où le plus court ( le temps le plus rapide) devrait se classer n°1.

Les doublons

Dans Excel, la fonction RANG attribuera des valeurs en double au même rang. Par exemple, si une certaine valeur a un rang de 3 et qu’il existe deux instances de la valeur dans les données, la fonction RANG attribuera aux deux instances un rang de 3. Le prochain rang attribué sera 5 et aucune valeur ne sera attribué un rang de 4. Si les rangs ex aequo posent problème, une solution de contournement consiste à utiliser une stratégie de bris d’égalité.

Comment utiliser la fonction RANG dans Excel ?

Pour comprendre les utilisations de la fonction, considérons quelques exemples.

Supposons que l’on nous donne une liste d’élèves avec leurs moyennes en classe. Nous souhaitons les classer en fonction des moyennes de fin d’année. Voir la capture ci-dessous:

Pour classer les élèves par ordre décroissant, nous utiliserons la formule suivante :

=RANG(D2;(D$2:D$9);0)

Formule RANG Excel - calculer le rang des élèves

Voici le résultat que nous obtenons :

Comment classer les données dans Excel de manière unique (sans doublons)

Comme vu ci-dessus, la fonction RANG donne aux nombres en double le même rang. Cependant, la présence de numéros en double affecte les rangs des numéros suivants. Par exemple, comme indiqué ci-dessus, dans une liste de moyennes triés par ordre croissant, le nombre 16,50 apparaît deux fois avec un rang de 4. La valeur suivante (15,94) sera classée 6 (aucun nombre ne sera classé 5).

Si nous voulons des rangs uniques, nous pouvons utiliser la formule :

=RANG(D2;D$2:D$9;0)+NB.SI(D$2:D2;D2)-1

Nous obtiendrons les résultats ci-dessous :

Pour l’ordre croissant, la formule serait :

=RANG(D2;D$2:D$9;1)+NB.SI(D$2:D2;D2)-1

Dans les deux formules, c’est la fonction NB.SI qui fait l’affaire. Nous avons utilisé NB.SI pour connaître le nombre de fois où le numéro classé s’est produit. Dans la formule NB.SI, la plage se compose d’une seule cellule (D$2:D2). Comme nous avons verrouillé uniquement la première référence (D$2), la dernière référence relative (D2) change en fonction de la ligne où la formule est copiée. Ainsi, pour la ligne 6, la plage s’étend à D$2:D6 et la valeur de D6 est comparée à chacune des cellules ci-dessus.

Ainsi, pour toutes les valeurs uniques et les premières occurrences de valeurs en double, NB.SI renvoie 1 ; et on soustrait 1 à la fin de la formule pour restaurer le rang d’origine.

Pour les rangs apparaissant la deuxième fois, NB.SI renvoie 2. En soustrayant 1, nous avons augmenté le rang de 1 point, évitant ainsi les doublons. S’il y a plus de 3 occurrences de la même valeur, NB.SI()-1 ajoutera 2 à leur classement, et ainsi de suite.

Vidéo : calculer le RANG sur Excel avec le format 1er/ère, 2ème

Merci de nous encourager sur YouTube

Fonction RANG Excel